home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er Special 83
/
64er_Magazin_Sonderheft_83_19xx_Markt__Technik_de_Side_B.d64
/
format 36-41
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-10-26
|
1KB
|
71 lines
10000 :
10001 :
10002 rem ***************************
10003 rem *** format spur 36 - 41 ***
10004 rem ***************************
10005 :
10006 :
10007 :
10008 rem *** resevieren puffer 2
10009 di$="":by$=""
10110 open15,8,15,"i":close15:open3,8,3,"#2"
10120 get#3,a$:ifasc(a$+chr$(0))<>2thenprint"bitte floppyrest":end
10200 rem
10210 rem *** lesen maschinenprogramme
10220 rem fuer floppy in zwischensp.
10230 :
10240 dimtf%(256)
10250 open1,8,0,"fp.formater.obj"
10260 get#1,lb$
10270 get#1,hb$
10280 fori=0to256
10290 get#1,y$:ify$=""theny$=chr$(0)
10300 y=asc(y$)
10310 tf%(i)=y
10320 ifst=64theni=256
10330 nexti
10340 close1
10500 print"[147] diskette einlegen und <return>"
10510 gett$:ift$<>chr$(13)then10510
10612 :
10613 rem *** id-kennung lesen
10614 open15,8,15
10620 open2,8,2,"#"
10630 print#15,"u1";2;0;18;0
10640 print#15,"b-p";2;162
10645 fori=0to1:get#2,by$:di$=di$+by$:next
10670 close2
10671 :
10672 rem *** laden formatierungsroutine
10673 rem in floppypuffer
10674 :
10680 mw$="m"+"-"+"w"
10690 fori=1536to1681
10700 x=tf%(i-1536)
10710 hb=int(i/256):lb=i-(hb*256)
10720 print#15,mw$+chr$(lb)chr$(hb)chr$(1)chr$(x)
10730 nexti
10733 :
10734 :
10735 rem *** laden sprungadresse in
10736 rem floppypuffer
10737 fori=36to41:print"spur";i;"formatieren..."
10740 print#15,mw$+chr$(0)chr$(5)chr$(3)chr$(76)chr$(41)chr$(6)
10743 :
10744 :
10745 rem *** uebergeben disk-id in
10746 rem floppypuffer
10747 :
10750 i1$=mid$(di$,1,1):i2$=mid$(di$,2,1):i1=asc(i1$):i2=asc(i2$)
10760 print#15,mw$+chr$(3)+chr$(5)+chr$(1)+chr$(i1)
10770 print#15,mw$+chr$(4)+chr$(5)+chr$(1)+chr$(i2)
10773 :
10774 :
10775 rem *** formatieren von spur 36
10776 rem bis spur 41
10777 :
10780 u3$="u"+"3"+" 3 0"+str$(i)+" 00"
10790 print#15,u3$:input#15,f,ft$,t,s:iffthenprintu3$;f;ft$;t;s
10792 next
11000 close15:close3